Datos de volcanes desde WolframAlpha

Descargar como Notebook

Una de las grandes evoluciones de Mathematica en las últimas versiones, es la capacidad de adquisición de datos con las características : curados, actuales y computables. Para presentar un ejemplo vamos a trabajar con el comando VolcanoData[ ].

Adquirimos como entidades, todos los volcanes activos y no activos en el planeta tierra.

volcanes = VolcanoData[]

Establecemos la posición geográfica de cada volcán en latitud y longitud, esta lista viene en el mismo orden de volcanes:

posicion = Map[VolcanoData[#, "Coordinates"] &, volcanes];

Eliminamos de las que no se encontraron datos o falló su búsqueda :

posicion1 = 
  Complement[posicion, {Missing["NotAvailable"]}, {Missing["RetrievalFailure"]}];


Cargamos datos de todos los países, SC[ ] es una función que nos convierte de las coordenadas de geoposicion(latitud, longitud) a coordenadas cartesianas:

paises = CountryData[];
SC[{lat_, lon_}] := 
  r {Cos[lon \[Degree]] Cos[lat \[Degree]], 
    Sin[lon  \[Degree]] Cos[lat  \[Degree]], Sin[lat \[Degree]]};
r = 6378.700;

Representamos sobre el globo terraqueo:

Graphics3D[{Opacity[0.8], Sphere[{0, 0, 0}, r], 
  Map[Line[Map[SC, CountryData[#, "SchematicCoordinates"], {-2}]] &, 
   paises], Red, PointSize[Medium], Map[Point[SC[#]] &, posicion1]}, 
 Boxed -> False, SphericalRegion -> False]

Para Colombia

volcanoes = 
  With[{entities = 
     GeoNearest["Volcano", 
      colombia, {All, Quantity[10, "Kilometers"]}]},
   Select[VolcanoData[entities, "Countries", "EntityAssociation"], 
    Length[#[[1]]] > 1 &]
   ];

GeoGraphics[{
  EdgeForm[Thin], Opacity[0.5], 
  Tooltip[Polygon[colombia], EntityValue[colombia, "Name"]],
  Opacity[0.2], 
  Tooltip @@@ 
   EntityValue[Union@Flatten@Values[volcanoes], {"Polygon", "Name"}],
  Opacity[0.7], Red, AbsolutePointSize[5], 
  Tooltip[Point[#1], #2] & @@@ 
   VolcanoData[Keys[volcanoes], {"Position", "Name"}]}, 
 ImageSize -> Medium
 ]