Entrada destacada

Caminos entre Esquinas de un Cuadrado

martes, 4 de julio de 2017

Números Normales


Un número real es un Número Normal en base b si en su expansión decimal en base b los dígitos se distribuyen de una forma uniforme. Es decir, los números de una cifra aparecen en la misma proporción, los de dos cifras, los de tres cifras, etc. O la probabilidad de encontrar una secuencia dada de dígitos a lo largo de su expansión decimal es igual que si se fuera a buscar cualquier otra secuencia de la misma cantidad de dígitos. Y se dice Número Normal Absoluto si esto ocurre para toda base. Los Números Normales fueron introducidos por Émile Borel en 1909, quien demostró la existencia de los Números Normales. Pero fue Sierpinski en 1916 quien construyó el primer Número Normal Absoluto.

Veamos algunos ejemplos :

El número de Champernowne

Es el número decimal entre cero y uno cuyas cifras decimales se obtienen concatenando los enteros positivos, su nombre se debe al matemático y economista británico D. G. Champernowne que lo publicó  como estudiante en 1933. En Mathematica se cuenta con el comando ChampernowneNumber[b] donde b específica la base en la que se desea construir. Así, el Número de Champernowne en base 10 con 100 cifras decimales es:

N[ChampernowneNumber[10], 100]
0.1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253546

Contamos la aparición de cada dígito al tomar cien millones de cifras decimales:

BarChart[Apply[Labeled, 
  Reverse[Sort[Tally[RealDigits[N[ChampernowneNumber[10], 100000000]][[1]]]],2],{1}]]



vemos que el número uno tiende a aparecer aproximadamente un 40 % más que las otras cifras que si tienden a presentarse de forma uniforme.

Ahora, con los números de dos dígitos. Para esto utilizamos el comando Partition[  ,2,1] ,para cien cifras decimales:

Tally[Sort[
  Partition[RealDigits[N[ChampernowneNumber[10], 100]][[1]], 2, 1]]]
{{{0, 1}, 1}, {{0, 2}, 1}, {{0, 3}, 1}, {{0, 4}, 1}, {{0, 5}, 1}, {{1, 0}, 1}, {{1, 1}, 2}, {{1, 2}, 3}, {{1, 3}, 2}, {{1, 4}, 2}, {{1, 5}, 2}, {{1, 6}, 1}, {{1, 7}, 1}, {{1, 8}, 1}, {{1, 9}, 1}, {{2, 0}, 1}, {{2, 1}, 2}, {{2, 2}, 2}, {{2, 3}, 3}, {{2, 4}, 2}, {{2, 5}, 2}, {{2, 6}, 1}, {{2, 7}, 1}, {{2, 8}, 1}, {{2, 9}, 1}, {{3, 0}, 1}, {{3, 1}, 2}, {{3, 2}, 2}, {{3, 3}, 2}, {{3, 4}, 3}, {{3, 5}, 2}, {{3, 6}, 1}, {{3, 7}, 1}, {{3, 8}, 1}, {{3, 9}, 1}, {{4, 0}, 1}, {{4, 1}, 2}, {{4, 2}, 2}, {{4, 3}, 2}, {{4, 4}, 2}, {{4, 5}, 3}, {{4, 6}, 1}, {{4, 7}, 1}, {{4, 8}, 1}, {{4, 9}, 1}, {{5, 0}, 1}, {{5, 1}, 2}, {{5, 2}, 2}, {{5, 3}, 2}, {{5, 4}, 2}, {{5, 6}, 1}, {{6, 1}, 1}, {{6, 2}, 1}, {{6, 3}, 1}, {{6, 4}, 1}, {{6, 7}, 1}, {{7, 1}, 1}, {{7, 2}, 1}, {{7, 3}, 1}, {{7, 4}, 1}, {{7, 8}, 1}, {{8, 1}, 1}, {{8, 2}, 1}, {{8, 3}, 1}, {{8, 4}, 1}, {{8, 9}, 1}, {{9, 1}, 1}, {{9, 2}, 1}, {{9, 3}, 1}, {{9, 4}, 1}, {{9, 5}, 1}}

Para diez millones de cifras decimales:

BarChart[Apply[Framed, 
  Reverse[Tally[
    Sort[Partition[
      RealDigits[N[ChampernowneNumber[10], 10000000]][[1]], 2, 1]]], 
   2], {2}]]



Observamos que existen números de dos cifras que aparecen más que los otros.

Veamos los números de tres cifras, primeras cien cifras decimales:

Tally[Sort[
  Partition[RealDigits[N[ChampernowneNumber[10], 100]][[1]], 3, 1]]]
{{{0, 1, 1}, 1}, {{0, 2, 1}, 1}, {{0, 3, 1}, 1}, {{0, 4, 1}, 1}, {{0, 5, 1}, 1}, {{1, 0, 1}, 1}, {{1, 1, 1}, 1}, {{1, 1, 2}, 1}, 
{{1, 2, 1}, 1}, {{1, 2, 2}, 1}, {{1, 2, 3}, 1}, {{1, 3, 1}, 1}, 
{{1, 3, 2}, 1}, {{1, 4, 1}, 1}, {{1, 4, 2}, 1}, {{1, 5, 1}, 1}, 
{{1, 5, 2}, 1}, {{1, 6, 1}, 1}, {{1, 7, 1}, 1}, {{1, 8, 1}, 1}, 
{{1, 9, 2}, 1}, {{2, 0, 2}, 1}, {{2, 1, 2}, 1}, {{2, 1, 3}, 1}, 
{{2, 2, 2}, 1}, {{2, 2, 3}, 1}, {{2, 3, 2}, 1}, {{2, 3, 3}, 1}, 
{{2, 3, 4}, 1}, {{2, 4, 2}, 1}, {{2, 4, 3}, 1}, {{2, 5, 2}, 1}, 
{{2, 5, 3}, 1}, {{2, 6, 2}, 1}, {{2, 7, 2}, 1}, {{2, 8, 2}, 1}, 
{{2, 9, 3}, 1}, {{3, 0, 3}, 1}, {{3, 1, 3}, 1}, {{3, 1, 4}, 1}, 
{{3, 2, 3}, 1}, {{3, 2, 4}, 1}, {{3, 3, 3}, 1}, {{3, 3, 4}, 1}, 
{{3, 4, 3}, 1}, {{3, 4, 4}, 1}, {{3, 4, 5}, 1}, {{3, 5, 3}, 1}, 
{{3, 5, 4}, 1}, {{3, 6, 3}, 1}, {{3, 7, 3}, 1}, {{3, 8, 3}, 1}, 
{{3, 9, 4}, 1}, {{4, 0, 4}, 1}, {{4, 1, 4}, 1}, {{4, 1, 5}, 1}, 
{{4, 2, 4}, 1}, {{4, 2, 5}, 1}, {{4, 3, 4}, 1}, {{4, 3, 5}, 1},
{{4, 4, 4}, 1}, {{4, 4, 5}, 1}, {{4, 5, 4}, 1}, {{4, 5, 6}, 1}, 
{{4, 6, 4}, 1}, {{4, 7, 4}, 1}, {{4, 8, 4}, 1}, {{4, 9, 5}, 1}, 
{{5, 0, 5}, 1}, {{5, 1, 5}, 1}, {{5, 1, 6}, 1}, {{5, 2, 5}, 1}, 
{{5, 2, 6}, 1}, {{5, 3, 5}, 1}, {{5, 3, 6}, 1}, {{5, 4, 5}, 1}, 
{{5, 4, 6}, 1}, {{5, 6, 7}, 1}, {{6, 1, 7}, 1}, {{6, 2, 7}, 1}, 
{{6, 3, 7}, 1}, {{6, 4, 7}, 1}, {{6, 7, 8}, 1}, {{7, 1, 8}, 1}, 
{{7, 2, 8}, 1}, {{7, 3, 8}, 1}, {{7, 4, 8}, 1}, {{7, 8, 9}, 1}, 
{{8, 1, 9}, 1}, {{8, 2, 9}, 1}, {{8, 3, 9}, 1}, {{8, 4, 9}, 1}, 
{{8, 9, 1}, 1}, {{9, 1, 0}, 1}, {{9, 2, 0}, 1}, {{9, 3, 0}, 1}, 
{{9, 4, 0}, 1}, {{9, 5, 0}, 1}}

Para las primeros diez millones de cifras decimales :

BarChart[Apply[Framed, 
  Reverse[Tally[
    Sort[Partition[
      RealDigits[N[ChampernowneNumber[10], 10000000]][[1]], 3, 1]]], 
   2], {2}]]



Observamos lo mismo que para los números de dos cifras, existen algunos que aparecen un número mayor de veces. Lo sorprendente es que pese a esta evidencia computacional en contra se ha demostrado que el Número de Champernowne es Normal en base 10.

El número de Copeland - Erdös

Es el número decimal entre cero y uno cuyas cifras decimales se obtienen concatenando los números primos. Construyamos el Número de Coperland-Erdös hasta el décimo número primo.

cop = Flatten[Prepend[IntegerDigits[Table[Prime[n], {n, 10}]], 0]];
N[FromDigits[{cop, 1}], Length[cop] - 1]

0.2357111317192329

Veamos el número de veces que aparece cada dígito al tomar el primer millón de números primos en su conformación:

BarChart[Apply[Labeled, 
  Reverse[Sort[
    Tally[Flatten[
      Prepend[IntegerDigits[Table[Prime[n], {n, 1000000}]], 0]]]], 
   2], {1}]]



El dígito uno tiende a aparecer más que los otros dígitos, seguido por el tres, siete y nueve y posteriormente los demás de forma uniforme.

Para los números de dos cifras:

BarChart[Apply[Framed, 
  Reverse[Sort[
    Tally[Partition[
      Flatten[IntegerDigits[Table[Prime[n], {n, 1000000}]]], 2, 1]]], 
   2], {2}]]



Y de tres cifras :

BarChart[Apply[Framed, 
  Reverse[Sort[
    Tally[Partition[
      Flatten[IntegerDigits[Table[Prime[n], {n, 1000000}]]], 3, 1]]], 
   2], {2}]]



Al igual que en el Número de Champernowne, pese a toda la evidencia computacional, en 1946 se demostró que es un Número Normal en base 10, por Arthur Herbert Copeland y Paul Erdös, de ahí su nombre.

La constante Pi

El número más importante de la geometría, que se obtiene como la razón entre el perímetro de una circunferencia y su diámetro. Se sabe que es irracional, trascendente, pero se desconoce si es un Número Normal, se conjetura que sí lo es.

Cómo se distribuye la aparición de cada uno de los dígitos en el primer millón de cifras decimales de Pi.

BarChart[Apply[Labeled, 
  Reverse[Sort[Tally[RealDigits[N[Pi, 1000000]][[1]]]], 2], {1}]]



Los números de dos cifras también en el primer millón de cifras decimales.

BarChart[Apply[Framed, 
  Reverse[Sort[
    Tally[Partition[RealDigits[N[Pi, 1000000]][[1]], 2, 1]]], 
   2], {2}]]


Los números de tres cifras en el primer millón de cifras decimales de Pi.

BarChart[Apply[Framed, 
  Reverse[Sort[
    Tally[Partition[RealDigits[N[Pi, 1000000]][[1]], 3, 1]]], 
   2], {2}]]



Del número Pi se tiene toda la evidencia computacional de ser un Número Normal en base 10, pero no se tiene aún una demostración formal de este hecho.

Como se ha mencionado varias veces a lo largo del Blog, las pruebas computacionales son evidencias de un hecho pero no son concluyentes para afirmar, únicamente para negar (como  contraejemplo).

En demonstrations.wolfram.com se pueden encontrar desarrollos hechos por los usuarios de Mathematica, allí tengo algunos aportes entre los que quiero destacar ahora http://demonstrations.wolfram.com/FindingStringsOfDigitsInTheDecimalDigitsOfFamousNumbers/ donde podemos cualquier número buscarlo entre las cifras decimales de los más importantes números irracionales.

Ejercicio

1. Al tomar un millón de números primos para la conformación del Número de Copeland - Erdös, cuántas cifras decimales tiene el número?

2. Realizar el estudio computacional de la aparición de los números de cuatro cifras en la constante Pi.

3. Realizar el estudio computacional de la Normalidad de los números e (la constante de Euler) y \[Phi] (el número áureo).


Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas


No hay comentarios.:

Publicar un comentario