Vamos a considerar inicialmente dos flechas, una anclada al origen y otra anclada al punto final de la primera, la primera gira en el sentido positivo y la segunda puede girar dos, tres veces más rápido, que la primera, en sentido positivo o negativo y tiene una longitud variable de a unidades. Trazaremos el recorrido de la punta de la segunda flecha.
La primera flecha tiene por punto inicial (0,0) y por punto final (Cos(t),Sen(t)), la segunda tiene por punto inicial (Cos(t),Sen(t)) y por punto final
(Cos(t),Sen(t))+a (Cos(n t),Sen(n t)) = (Cos(t) + a Cos(n t),Sen(t) + a Sen(n t)).
Manipulate[
Show[Graphics[{Arrow[{{0, 0}, {Cos[t], Sin[t]}}], Green,
Circle[{0, 0}, 1], Orange,
Arrow[{{Cos[t], Sin[t]}, {Cos[t] + a Cos[k t],
Sin[t] + a Sin[k t]}}]}, PlotRange -> 3, Axes -> True],
ParametricPlot[{Cos[s] + a Cos[k s], Sin[s] + a Sin[k s]}, {s,
0.000001, t}]], {{a, 0.9}, 0,
2}, {k, {-3, -2, -1, 1, 2, 3, 4, 5, 6, 7}}, {t, 0, 2 Pi}]
Ahora la misma situación anterior, pero con tres flechas.
Manipulate[
Show[Graphics[{Arrow[{{0, 0}, {Cos[t], Sin[t]}}],
Arrow[{{Cos[t], Sin[t]}, {Cos[t] + a Cos[k t],
Sin[t] + a Sin[k t]}}],
Arrow[{{Cos[t] + a Cos[k t],
Sin[t] + a Sin[k t]}, {Cos[t] + a Cos[k t] + b Cos[p t],
Sin[t] + a Sin[k t] + b Sin[p t]}}]}, PlotRange -> 5,
Axes -> True],
ParametricPlot[{Cos[s] + a Cos[k s] + b Cos[p s],
Sin[s] + a Sin[k s] + b Sin[p s]}, {s, 0.000001, t}]], {a, 0,
2}, {k, {-3, -2, 2, 3, 4, 5, 6, 7}}, {b, 0,
2}, {p, {-3, -2, 2, 3, 4, 5, 6, 7}}, {t, 0, 2 Pi}]
Ahora, son diez flechas con longitud de 1/n con respecto a la primera para la enésima flecha. Pero el recorrido de la punta de la última flecha traza una figura. La lista inicial aa determina la velocidad y sentido de cada flecha, positivo es en sentido anti horario y negativo en sentido horario.
aa = {2, 6, -4, 10, 2, -10, -12, 6, 2, -20, -10, 10};
Manipulate[
Show[Graphics[{Arrowheads[0.01],
Table[Arrow[{{Sum[Cos[aa[[n]] t]/n, {n, m - 1}],
Sum[Sin[aa[[n]] t]/n, {n, m - 1}]}, {Sum[
Cos[aa[[n]] t]/n, {n, m}],
Sum[Sin[aa[[n]] t]/n, {n, m}]}}], {m, 0, 12}]},
PlotRange -> 4, Axes -> True],
ParametricPlot[{Sum[Cos[aa[[n]] s]/n, {n, 12}],
Sum[Sin[aa[[n]] s]/n, {n, 12}]}, {s, 0, t}]], {t, 0.00001, Pi}]
La pregunta es cómo elegir adecuadamente la velocidad y sentido de cada flecha, esto tiene una respuesta sorprendente que veremos en una futura entrada.
Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas