Sombreado de una Región Polar

 Descargar como Notebook

El comando Filling  que se utiliza para el sombreado de regiones planas no sé si es posible utilizarlo para regiones polares, no he encontrado como hacerlo, entonces busque otra forma para hacerlo.

Sombreado de un pétalo de la rosa de cuatro pétalos r = Cos[2 t]

Construcción de un pétalo,

PolarPlot[Cos[2 t], {t, -Pi/4, Pi/4}, PlotStyle -> Directive[Pink], 

 Axes -> False]

sombreado del pétalo,

PolarPlot[Cos[2 t], {t, -Pi/4, Pi/4}, PlotStyle -> Directive[Pink], 

  Axes -> False] /. Line -> Polygon

junto a la rosa,

Show[PolarPlot[Cos[2 t], {t, -Pi/4, Pi/4}, 

   PlotStyle -> Directive[Pink], Axes -> False] /. Line -> Polygon, 

 PolarPlot[Cos[2 t], {t, 0, 2 Pi}]]

Sombreado de un pétalo de la rosa de tres pétalos r = Cos[3 t]

Show[PolarPlot[Cos[3 t], {t, -Pi/6, Pi/6}, 

   PlotStyle -> Directive[Pink], Axes -> False] /. Line -> Polygon, 

 PolarPlot[Cos[3 t], {t, 0, 2 Pi}]]

Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas

Frase Célebre de Michael Atiyah

 El "ser o no ser" de Hamlet equivale 

en profundidad y brevedad a la Fórmula de Euler.

Michael Atiyah

Número Primo de 6400 cifras con 6399 nueves y un ocho

 Descargar como Notebook

En 1991 Harvey Dubner encuentra el número 10^6400 - 10^6352 - 1 que es un número primo con 6399 nueves y un ocho en la posición 48.

pp = 10^6400 - 10^6352 - 1

PrimeQ[pp]

True

Length@Characters@ToString[pp]

6400

Position[Characters@ToString[pp], "8"]

{{48}}



Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas

Frase Célebre de Thomas Henry Huxley

La práctica matemática es puramente deductiva.
El matemático parte de unas simples proposiciones cuya demostración es tan obvia que merecen el calificativo de evidentes por sí mismas, con lo que el resto de su trabajo consiste en desarrollar sutiles deducciones a partir de ellas.
El estudio de las matemáticas no requiere nada de observación, experimentación, inducción o casualidad.

Thomas Henry Huxley

Funciones Vectoriales

 Descargar como Notebook

Representación de los vectores posición P(t), velocidad v(t) y aceleración a(t) en una función vectorial en el plano.

f1[t_] := {t^2 - 3, t}

f2[t_] := 2 {Cos[t], Sin[t]}

f3[t_] := {Cos[t] (1 - 2 Cos[t]), (1 - 2 Cos[t]) Sin[t]}

f4[t_] := 2 {Cos[t] Cos[2 t], Cos[2 t] Sin[t]}

fun[f_] := 

 ParametricPlot[f[t], {t, -4, 4}, Ticks -> None, PlotRange -> 3, 

  ImageSize -> {50, 50}]

Manipulate[

 Show[ParametricPlot[f[t], {t, -4, 4}, PlotRange -> 4], 

  Graphics[{Text["P(t)", f[r]/2 + {0, 0.2}], 

    Text["v(t)", f[r] + 1.1 f'[r]], Text["a(t)", f[r] + f''[r] 1.03], 

    Red, Arrow[{f[r], f[r] + f'[r]}], Green, Arrow[{{0, 0}, f[r]}], 

    Pink, Arrow[{f[r], f''[r] + f[r]}]}]], {r, -3, 

  3}, {{f, f1, "r(t)"}, {f1 -> fun[f1], f2 -> fun[f2], f3 -> fun[f3], 

   f4 -> fun[f4]}}]

Representación de los vectores posición, velocidad y aceleración en una función vectorial en el espacio .

Clear[a]

f1[t_] := {t^2 - 3, t^2, t}

f2[t_] := {2 Cos[t], 2 Sin[t], t/2}

f3[t_] := {3 Cos[t], Sin[t], 2}

f4[t_] := {t Cos[t], t Sin[t], t}/5

fun[f_, p_] := 

 ParametricPlot3D[f[t], {t, -p, p}, Ticks -> None, PlotRange -> 3, 

  ImageSize -> {50, 50}]

func[f_, p_] := 

 ParametricPlot3D[f[t], {t, -p, p}, Axes -> True, 

  AxesOrigin -> {0, 0, 0}, PlotRange -> 4]

g1 = func[f1, 3];

g2 = func[f2, 30];

g3 = func[f3, 4];

g4 = func[f4, 30];

Manipulate[{gra, a} = 

  Switch[f, f1, {g1, 1.2}, f2, {g2, 3}, f3, {g3, 3}, f4, {g4, 15}]; 

 Show[gra, 

  Graphics3D[{Text["P(t)", f[r]/2 + {0, 0, 0.2}], 

    Text["v(t)", f[r] + 1.1 f'[r]], Text["a(t)", f[r] + f''[r] 1.03], 

    Red, Arrow[{f[r], f[r] + f'[r]}], Green, Arrow[{{0, 0, 0}, f[r]}],

     Pink, Arrow[{f[r], f''[r] + f[r]}]}]], {r, -a, 

  a}, {{f, f1, "r(t)"}, {f1 -> fun[f1, 5], f2 -> fun[f2, 50], 

   f3 -> fun[f3, 4], f4 -> fun[f4, 50]}}]

Cambio del vector Tangente Unitario - Curvatura

Aunque la función no se encuentra parametrizada con respecto a la longitud de curva, se evidencia el cambio del vector tangente unitario con respecto a la curvatura de la parábola.

graf = ContourPlot[x^2 + y^2 == 1, {x, -2, 2}, {y, -2, 2}, 

   Axes -> True, ContourStyle -> {Green, Dashed}];

Manipulate[cur = 2./(4 r^2 + 1)^(3/2); 

 Row[{Show[ParametricPlot[{t^2 + 1, t}, {t, -3, 3}], 

    Graphics[{Red, 

      Arrow[{{r^2 + 1, 

         r}, {2 r, 1}/Sqrt[4 r^2 + 1] + {r^2 + 1, r}}]}], 

    ImageSize -> Small], 

   Show[graf, 

    Graphics[{Red, Arrow[{{0, 0}, {2 r, 1}/Sqrt[4 r^2 + 1]}]}], 

    ImageSize -> Small, 

    PlotLabel -> Row[{"Curvatura = ", cur}]]}], {{r, -2, "t"}, -3, 3},

  ContentSize -> {400, 240}]

Sistema  de vectores TNB y Planos osculador y normal

Clear[a, bb]

f1[t_] := {t^2 - 3, t^2, t}

f2[t_] := {2 Cos[t], 2 Sin[t], t/2}

f3[t_] := {3 Cos[t], Sin[t], 2}

f4[t_] := {t Cos[t], t Sin[t], t}/5

fun[f_, p_] := 

 ParametricPlot3D[f[t], {t, -p, p}, Ticks -> None, PlotRange -> 3, 

  ImageSize -> {50, 50}]

func[f_, p_] := 

 ParametricPlot3D[f[t], {t, -p, p}, Axes -> True, 

  AxesOrigin -> {0, 0, 0}, PlotRange -> 4]

g1 = func[f1, 3];

g2 = func[f2, 30];

g3 = func[f3, 4];

g4 = func[f4, 30];

gg = Graphics3D[{Point[{0, 0, -10}]}];

Manipulate[

 tt[t_] := Normalize[f'[t]];

 nn[t_] := Normalize[f''[t]];

 bb[t_] := Normalize@Cross[f'[t], f''[t]];

 

 {gra, a} = 

  Switch[f, f1, {g1, 1.2}, f2, {g2, 3}, f3, {g3, 3}, f4, {g4, 15}]; 

 Show[gra, 

  Graphics3D[{Text["T", f[r] + 1.1 tt[r]], 

    Text["N", f[r] + nn[r] 1.03], Text["B", f[r] + bb[r] 1.03], Red, 

    Arrow[{f[r], f[r] + tt[r]}], Green, Arrow[{{0, 0, 0}, f[r]}], 

    Pink, Arrow[{f[r], nn[r] + f[r]}], Orange, 

    Arrow[{f[r], bb[r] + f[r]}]}], 

  If[pn, ContourPlot3D[

    Dot[f'[r], {x, y, z} - f[r]] == 0, {x, -4, 4}, {y, -4, 4}, {z, -4,

      4}, Mesh -> None, ContourStyle -> Opacity[0.6]], gg], 

  If[po, ContourPlot3D[

    Dot[bb[r], {x, y, z} - f[r]] == 0, {x, -4, 4}, {y, -4, 4}, {z, -4,

      4}, Mesh -> None, ContourStyle -> Opacity[0.6]], gg]], {r, -a, 

  a}, {{f, f1, "r(t)"}, {f1 -> fun[f1, 5], f2 -> fun[f2, 50], 

   f3 -> fun[f3, 4], f4 -> fun[f4, 50]}}, {{pn, False, 

   "Plano Normal"}, {False, True}}, {{po, False, 

   "Plano Osculador"}, {False, True}}, ControlPlacement -> Left]

Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas