Pelota Rebotando dentro de una Circunferencia

 Descargar como Notebook

Se deja caer una pelota dentro de una circunferencia y rebota con sus lados bajo la acción únicamente de la fuerza de gravedad .

g = 9.81;

tmax = 10;

rebote = ReflectionTransform[{-x[t], -y[t]}][{x'[t], y'[t]}];

solucion[x0_, y0_] := 

  NDSolveValue[{y''[t] == -g, x''[t] == 0, x'[0] == 0, y'[0] == 0, 

    x[0] == x0, y[0] == y0, 

    WhenEvent[

     x[t]^2 + y[t]^2 == 1, {x'[t], y'[t]} -> Evaluate[rebote]]}, {x, 

    y}, {t, 0, tmax}];

{xf1, yf1} = solucion[0.5, 0.7];(*Punto inicial*)

Manipulate[

 Show[ParametricPlot[{xf1[t], yf1[t]}, {t, 0, ttt}, PlotRange -> 1], 

  Graphics[{{Red, Circle[{0, 0}, 1]}, {PointSize[0.03], Orange, 

     Point[{xf1[ttt], yf1[ttt]}]}}], Ticks -> None, 

  Background -> Black], {ttt, 0.00001, tmax, 0.001, Trigger, 

  DefaultDuration -> 15}]

Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas

Frase Célebre de Cédric Villani

 Las matemáticas nos permiten 

ir más allá de nuestra intuición 

y explorar territorios fuera de nuestro alcance.

Cédric Villani

Sólidos de Revolución: Casquetes Cilíndricos

 Descargar como Notebook

Dada la región limitada por f(x)=2x²- x³ y el eje x, determinar el volumen del sólido que genera al hacerla girar con respecto al eje y.

Visualización utilizando el método de Casquetes Cilíndricos. 

Para un rectángulo iésimo. 

f[t_] := 2 t^2 - t^3

Manipulate[h = 2/n; 

 Show[RevolutionPlot3D[{{t, f[t]}, {t, 0}}, {t, 0, 2}, {a, 

    0, \[Theta]}, AxesOrigin -> {0, 0, 0}, 

   AxesLabel -> {"X", "Y", "Z"}, PlotStyle -> {{Blue, Opacity[0.2]}}, 

   PlotRange -> 2, Mesh -> 1], 

  RevolutionPlot3D[{{h (i + t), 0}, {h (i + t), f[h i]}, {h i, 

     t f[h i]}, {h (i + 1), t f[h i]}}, {t, 0, 1}, {a, 0, \[Theta]}, 

   PlotStyle -> {{Red, Opacity[0.5]}}]], {{n, 4, "Subdivisiones (n)"},

   1, 10, 1}, {i, 1, n - 1, 1}, {Θ, 0.01, 2 Pi}]

Sólido aproximado por varios rectángulos,

f[t_] := 2 t^2 - t^3

Manipulate[h = 2/n; 

 Show[RevolutionPlot3D[{{t, f[t]}, {t, 0}}, {t, 0, 2}, {a, 

    0, \[Theta]}, AxesOrigin -> {0, 0, 0}, 

   AxesLabel -> {"X", "Y", "Z"}, PlotStyle -> {{Blue, Opacity[0.2]}}, 

   PlotRange -> {{-2, 2}, {-2, 2}, {-0.5, 2}}, Mesh -> 1], 

  RevolutionPlot3D[

   Evaluate@

    Flatten[Table[{{h (i + t), 0}, {h (i + t), f[h i]}, {h i, 

        t f[h i]}, {h (i + 1), t f[h i]}}, {i, n - 1}], 1], {t, 0, 

    1}, {a, 0, Θ}, PlotStyle -> {{Opacity[0.4]}}, 

   Mesh -> None]], {{n, 4, "Subdivisiones (n)"}, 1, 10, 1}, {Θ,

   0.01, 2 Pi, ControlType -> Trigger, DefaultDuration -> 20}]

Imagen Arriba

Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas