Analicemos el ejemplo, realizado en la entrada de Plano Tangente del 26 de Febrero de 2019, que realizamos para determinar el plano tangente a la superficie
en el punto (1, -2).
g1 = Plot3D[x^2 + 2 x - 4 y^2, {x, -3, 3}, {y, -3, 3},
PlotStyle -> Opacity[0.5]]; cx =
ContourPlot3D[x == 1, {x, -3, 3}, {y, -3, 3}, {z, -40, 30},
Mesh -> None, ContourStyle -> {Opacity[0.3], Red}];
cy = ContourPlot3D[y == -2, {x, -3, 3}, {y, -3, 3}, {z, -40, 30},
Mesh -> None, ContourStyle -> {Opacity[0.3], Yellow}];
px = ParametricPlot3D[{1, t, 3 - 4 t^2}, {t, -3, 3},
PlotStyle -> {Red, Thickness[0.015]}]; py =
ParametricPlot3D[{t, -2, t^2 + 2 t - 16}, {t, -3, 3},
PlotStyle -> {Blue, Thickness[0.015]}];
punto = Graphics3D[Point[{1, -2, -11}]];
tx = ParametricPlot3D[{1, t, 16 t + 19}, {t, -3, 3},
PlotStyle -> {Green, Thickness[0.01]}];
ty = ParametricPlot3D[{t, -2, 4 t - 17}, {t, -3, 3},
PlotStyle -> {Pink, Thickness[0.01]}];
plano = ContourPlot3D[
z == 4 x + 16 y + 15, {x, -3, 3}, {y, -3, 3}, {z, -30, 10},
ContourStyle -> Orange, PlotPoints -> 60, Mesh -> 2];
Manipulate[If[planox == True, planoy = False];
If[planoy == True, planox = False];
Row[{Show[g1, If[planox, cx, punto], If[planoy, cy, punto],
If[curvax, px, punto], If[curvay, py, punto],
If[TangenteX, tx, punto], If[TangenteY, ty, punto],
If[pp, plano, punto], AxesOrigin -> {0, 0, 0},
AxesLabel -> {"X", "Y", "Z"}, ImageSize -> 300],
Which[planox,
Show[Plot[{3 - 4 y^2, 16 y + 19}, {y, -3, 3},
PlotStyle -> {Red, Green}, AxesLabel -> {"Y", "Z"},
ImageSize -> 300],
Graphics[{Red, Point[{-2, -13}], Text["m = 16", {2, 40}], Dashed,
Line[{{-2, 0}, {-2, -13}, {0, -13}}]}]], planoy,
Show[Plot[{x^2 + 2 x - 16, 4 x - 17}, {x, -3, 3},
PlotStyle -> {Blue, Pink}, AxesLabel -> {"X", "Z"},
ImageSize -> 300],
Graphics[{Green, Point[{1, -13}], Text["m = 4", {-2, -28}],
Dashed, Line[{{1, 0}, {1, -13}, {0, -13}}]}]]]}],
Text[Style["Plano x = 1", Bold]], {planox, {False,
True}}, {curvax, {False, True}}, {TangenteX, {False, True}},
Text[Style["Plano y = -2", Bold]], {planoy, {False,
True}}, {curvay, {False, True}}, {TangenteY, {False, True}},
Text[Style["Plano Tangente", Bold]], {{pp, False,
"Plano Tangente"}, {False, True}}]
Al cortar la superficie con el plano transversal x = 1, determinamos una curva en un plano de ejes Y - Z, de ecuación en ese plano: z = 3 - 4y², que lo obtenemos reemplazando x = 1 en z = x² + 2x - 4y².
Para determinar la pendiente de la recta tangente podemos:
o sin necesidad de reemplazar primero por x = 1, podemos derivar con respecto a y suponiendo que x es una constante:
esto se denomina la derivada parcial con respecto a y.
Igualmente, al cortar la superficie con el plano transversal y = -2, determinamos una curva en un plano de ejes X - Z, de ecuación en ese plano: z = x²+2x-16, que lo obtenemos reemplazando y = -2 en
z = x² + 2x - 4y².
Para determinar la pendiente de la recta tangente podemos:
esto se denomina la derivada parcial con respecto a x.
Estas derivadas las podemos representar como:
Show[ContourPlot[4 x + 16 y + 15, {x, -3, 3}, {y, -3, 3},
Axes -> True, AxesLabel -> {"X", "Y"}],
Table[ContourPlot[4 x + 16 y + 15 == c, {x, -3, 3}, {y, -3, 3},
ContourLabels -> All,
ContourStyle -> {Dashed, Hue[Cos[c]]}], {c, {-13, 3, -9}}],
Graphics[{{Blue, Point[{1, -2}], Point[{2, -2}],
Text["(1,-1)", {1, -0.8}], Text["(1,-2)", {0.8, -2.2}],
Text["(2,-2)", {2.4, -2}], Point[{1, -1}]}, {Green,
Arrow[{{1, -2}, {1, -1}}]}, {Pink,
Arrow[{{1, -2}, {2, -2}}]}, {Text[
"dz/dy = 16", \
{0.5, -1.5}], Text["dz/dx = 4", {1.5, -2.5}]}}]]
En el plano tangente, el punto (1,-2) se encuentra en una curva de nivel c = -13, al movernos una unidad, en x, hacia la derecha (la derivada es el cambio con respecto a una unidad positiva) llegamos a una curva de nivel c = -9, hemos aumentado 4 unidades.
Ahora, nuevamente desde el punto (1,-2) al movernos una unidad, en y, hacia arriba encontramos una curva de nivel c = 3, hemos aumentado 16 unidades.
Veamos que esto no es exacto si lo hacemos sobre la superficie:
Show[ContourPlot[x^2 + 2 x - 4 y^2, {x, -3, 3}, {y, -3, 3},
Axes -> True, AxesLabel -> {"X", "Y"}],
Table[ContourPlot[x^2 + 2 x - 4 y^2 == c, {x, -3, 3}, {y, -3, 3},
ContourLabels -> All,
ContourStyle -> {Dashed, Hue[Cos[c]]}], {c, {-13, 3, -9}}],
Graphics[{{Blue, Point[{1, -2}], Point[{2, -2}],
Text["(1,-1)", {1, -0.8}], Text["(1,-2)", {0.8, -2.2}],
Text["(2,-2)", {2.4, -2}], Point[{1, -1}]}, {Green,
Arrow[{{1, -2}, {1, -1}}]}, {Pink,
Arrow[{{1, -2}, {2, -2}}]}, {Text[
"dz/dy = 16",
{0.5, -1.5}], Text["dz/dx = 4", {1.5, -2.5}]}}]]
Ahora, los cambios que realmente interesan son diferenciales (pequeños), consideremos cambios en x y y de 1/10 = 0.1, esto respectivamente es z corresponde a cambios de 4/10 = 0.4 y 16/10 =1.6
Manipulate[
Show[ContourPlot[
x^2 + 2 x - 4 y^2, {x, -3 + 3.8 t, 3 - 1.8 t}, {y, -3 + 0.8 t,
3 - 4.8 t}, Axes -> True, AxesLabel -> {"X", "Y"}],
Table[ContourPlot[
x^2 + 2 x - 4 y^2 == c, {x, -3 + 3.8 t,
3 - 1.8 t}, {y, -3 + 0.8 t, 3 - 4.8 t}, ContourLabels -> All,
ContourStyle -> {Dashed, Hue[Cos[c]]}], {c,
If[t < 0.5, {-13, 3, -9}, {-13, -11.4, -12.6}]}],
Graphics[{Text[
"dz/dy = 16", {0.5 + 0.46 t, -1.5 - 0.45 t}],
Text["dz/dx = 4", {1.5 - 0.45 t, -2.5 + 0.46 t}],
Text["(1,-2)", {0.8 + 0.18 t, -2.2 + 0.18 t}], {Green,
Arrow[{{1, -2}, {1, -1 - 0.9 t}}]}, {Pink,
Arrow[{{1, -2}, {2 - 0.9 t, -2}}]},
If[rec, {Red, Dashed,
Line[{{0.8, -2.2}, {1.2, -2.2}, {1.2, -1.8}, {0.8, -1.8}, {0.8, ²
-2.2}}]}],
If[t > 0.8, {{Blue, Point[{1, -2}], Point[{1.1, -2}],
Text["(1.1,-2)", {1.13, -2}], Point[{1, -1.9}],
Text["(1,-1.9)", {1, -1.88}]}}, {{Blue, Point[{1, -2}],
Point[{2, -2}], Text["(1,-1)", {1, -0.8}],
Text["(2,-2)", {2.4, -2}], Point[{1, -1}]}}]}]], {{rec, False,
"Rectángulo"}, {False, True}}, {{t, 0, "Zoom"}, 0, 1, Trigger}]
Observamos, que la correspondencia es muy buena sobre la superficie.
Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas
