Curva Podaria

Descargar como Notebook

Dada una curva C y un punto fijo P, se llama Podaria de la curva C con respecto al punto P al lugar geométrico de las proyecciones ortogonales de P sobre las tangentes de la curva C.

En el siguiente ejemplo el punto R pertenece a la Podaria de la curva C con respecto al punto P.

Show[ContourPlot[{x^2 + x y == y, y == 0, x == -1}, {x, -3, 
   3}, {y, -3, 3}], 
 Graphics[{Point[{-1, -1}], Text["P", {-1.1, -1.1}], 
   Text["C", {0.9, 1}], Red, Point[{-1, 0}], Text["R", {-1.1, 0.1}]}]]

Dada la curva F(t) y un punto P, su recta tangente para t = t', tiene por ecuación:

F (t') + F' (t') s, con s en los reales.

La recta perpendicular a la tangente que pasa por el punto P, tiene por ecuación:

P + {{0, 1}, {-1, 0}} F' (t') u, con u en los reales.

El punto de corte entre las rectas anteriores, es:

Vamos a construir un aplicativo para determinar la Podaria de algunas curvas planas:

f1[t_] := {t, t^2}
f2[t_] := {t, t^3 - 3 t^2}
f3[t_] := {Cos[t], 4 Sin[t]}
f4[t_] := {t^3, t^2}
f5[t_] := {4 Cos[t]^3, 5 Sin[t]^3}
Manipulate[
 Show[ParametricPlot[{f[r] + t f'[r], 
    p + t Reverse[f'[r]] {1, -1}}, {t, -20, 20}, PlotRange -> 10], 
  ParametricPlot[f[t], {t, -50, 50}, PlotStyle -> Green], 
  ParametricPlot[{f[t] + 
     f'[t] (Dot[f'[t], p - f[t]]/Norm[f'[t]]^2)}, {t, -20.00001, r}, 
   PlotStyle -> Red], 
  Graphics[{Point[p], Point[f[r]], 
    Text["P", p + {-0.1, -0.1}]}]], {r, -20, 
  20}, {{f, f1, 
   "Curva C"}, {f1 -> "(t,t^2)", 
   f2 -> "(t,t^3-3t^2)", 
   f3 -> "(Cos[t],4Sin[t])", 
   f4 -> "(t^3,t^2)", 
   f5 -> "(4 Cos[t]^3,5 Sin[t]^3"}}, {p, {-5, -5}, {5, 5}}, 
 ControlPlacement -> Left]

Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas

Frase Célebre de William Paul Thurston

Las matemáticas no es acerca de
números, ecuaciones, computación o algoritmos:
es acerca del entendimiento.

William Paul Thurston

Punto de Fermat de un Triángulo o Punto de Torricelli

Descargar como Notebook

Dados tres puntos A, B y C, no alineados y por tanto vértices de un triángulo, se desea determinar un punto P tal que la suma de distancias de los tres vértices al punto P: PA + PB + PC sea mínima. El punto P se conoce como el Punto de Fermat de un triángulo.

Graphics[{Line[{{0, 0}, {2, 2}, {4, 0}, {0, 0}}], Text["A", {0, 0.1}],
   Text["B", {4, 0.1}], Text["C", {2, 2.1}], Text["P", {2.1, 1.1}], 
  Red, Dashed, Line[{{0, 0}, {2, 1}, {2, 2}}], 
  Line[{{2, 1}, {4, 0}}]}]

Este problema aparece en una carta privada que el matemático francés Pierre de Fermat (1601 - 1675) le envió al físico italiano Evangelista Torricelli (1608 - 1647). El problema fue resuelto por Torricelli, aunque su demostración fue publicada  en 1659 por su discípulo Vicenzo Viviani (1622-1703), también Bonaventura Cavalieri dio otra solución y el resultado es el siguiente:

En un triángulo cuyos ángulos son menores de 120º, el punto P cumple la condición siguiente:

ángulo (APB) = ángulo (BPC) = ángulo (CPA) = 120 º.

Torricelli demostró que si el punto cumplía esa condición la suma de distancias PA + PB + PC es mínima, la demostración corresponde a la construcción geométrica de l solución.

Consideremos P en el interior del triángulo ABC, y tomamos el triángulo APC que lo rotamos, con respecto al vértice A, un ángulo de 60^\[SmallCircle]en sentido contrario a las manecillas del reloj, obteniendo el triángulo AP'C'. Ahora moviendo el punto P buscamos alinear B, P, P' y C', y para ese punto P se obtiene el Punto de Fermat.

La razón, es sencilla pues al estar alineados es el menor valor de la suma de: 

BP + PP'+P'C',

por semejanza notamos que: PP' = AP y P'C' = PC, así el valor de:

BP + AP + PC

es mínimo.

pu = "✪"; a = {0, 0};
Manipulate[rot[th_] := {{Cos[th], Sin[th]}, {-Sin[th], Cos[th]}}; 
 Graphics[{Line[{a, b, c, a}], Text["A", a - {0.2, 0.2}], 
   Text["B", b + {0.2, 0.2}], Text["C", c + {0.2, 0.2}], 
   Text["P", p + {0.2, 0.2}], 
   If[EuclideanDistance[b, c.rot[Pi/3.]] + 0.0003 >= 
     EuclideanDistance[b, p] + EuclideanDistance[p, p.rot[Pi/3]] + 
      EuclideanDistance[p, c], 
    Text["Punto de Fermat", p - {0, 0.25}]], 
   If[th > 0.2, {Text["C'", c.rot[th] + {0.2, 0.2}], 
     Text["P'", p.rot[th] + {0.2, 0.2}]}], Text[pu, {0, 0}], Red, 
   Point[p.rot[th]], Point[c.rot[th]], Dashed, Line[{a, p, c, p, b}], 
   If[linea, {Green, Line[{b, c.rot[th]}]}], 
   If[apc, {Yellow, Opacity[0.5], Triangle[{a, p, c}]}], 
   If[th > 0.01, {Orange, Opacity[0.4], 
     Triangle[{a, p, c}.rot[th]]}]}, 
  PlotRange -> {{-3.5, 4.5}, {-0.3, 7}}], {{b, {4, 0}}, 
  Locator}, {{c, {3, 4}}, Locator}, {{p, {2, 1}}, Locator}, 
 Text["Para un punto P interior al triángulo, consideramos:"], {{apc, 
   False, "Triángulo APC"}, {False, True}}, 
 Text["Rotamos el triángulo APC 60º sobre el vértice A:"], {{th, 0, 
   "\[Theta]"}, 0, Pi/3, Trigger}, 
 Text["Unimos el vértice B con C':"], {linea, {False, True}}, 
 Text["Moviendo P, buscamos alinear B, P, P' y C'"], 
 ControlPlacement -> Left]

Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas

Frase Célebre de Sophie Germain

Álgebra es nada más que geometría, en palabras;
geometría es nada más que álgebra, en dibujos.

Sophie Germain