Transformaciones de Funciones

Descargar como Notebook

Consiste en los cambios que se pueden obtener sobre una función al pre-componer y pos-componer con respecto a funciones lineales.

Consideraremos la función:

f[x_] := Piecewise[{{x + 2, -1 <= x < 0}, {2, 0 <= x < 2}, {-x + 4, 

    2 <= x < 4}, {x - 4, 4 <= x <= 5}}, None]

Plot[f[x], {x, -5, 5}, GridLines -> All]

Pos - composición : Transformación en Y

Sea g(x) = c x + d, realizaremos la composición (g ∘ f)(x) = g(f(x)) = c f(x) + d, que afecta a la función en el eje Y. 

f[x_] := Piecewise[{{x + 2, -1 <= x < 0}, {2, 0 <= x < 2}, {-x + 4, 

    2 <= x < 4}, {x - 4, 4 <= x <= 5}}, None]

Manipulate[g[x_] := c x + d; 

 Show[Plot[{f[x], g[f[x]]}, {x, -6, 6}, 

   PlotLabel -> Row[{c, "f(x)", If[d >= 0, "+", ""], d}], 

   PlotStyle -> {{Dashed, Blue}, {Red, Thickness[0.01]}}, 

   PlotRange -> 8, GridLines -> All, AspectRatio -> 1], 

  Graphics[{Text["f(x)", {2.2, 2.2}]}]], {{c, 1}, -3, 3}, {{d, 0}, -3,

   3}]

Pre - composición : Transformación en X

Sea g(x) = a x + b, realizaremos la composición (f ∘ g)(x) = f(g(x)) = f(a x + b), que afecta a la función en el eje X. 

f[x_] := Piecewise[{{x + 2, -1 < x < 0}, {2, 0 < x < 2}, {-x + 4, 

    2 < x < 4}, {x - 4, 4 < x < 5}}, None]

Manipulate[g[x_] := a x + b; 

 Show[Plot[{f[x], f[a x + b]}, {x, -6, 6}, 

   PlotLabel -> Row[{"f(", a, "x", If[b >= 0, "+", ""], b, ")"}], 

   PlotStyle -> {{Dashed, Blue}, {Red, Thickness[0.01]}}, 

   PlotRange -> 8, GridLines -> All, AspectRatio -> 1], 

  Graphics[{Text["f(x)", {2.2, 2.2}]}]], {{a, 1}, -3, 3}, {{b, 0}, -3,

   3}]

Composiciones con g (x) = - x

Clear[f, gf, gfg]

f[x_] := Piecewise[{{x + 2, -1 < x < 0}, {2, 0 < x < 2}, {-x + 4, 

    2 < x < 4}, {x - 4, 4 < x < 5}}, None]

Manipulate[

 Plot[{f[x], 

   Evaluate@Switch[op, fg, f[-x], gf, -f[x], gfg, -f[-x]]}, {x, -5, 

   5}, PlotRange -> 5, 

  PlotStyle -> {{Dashed, Blue}, {Red, Thickness[0.01]}}, 

  GridLines -> All, 

  AspectRatio -> 1], {{op, "", "Composición: Roja"}, {fg -> "f(-x)", 

   gf -> "-f(x)", gfg -> "-f(-x)"}}]

Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas

Frase Célebre de Sandra García

Las matemáticas te permiten escapar de la realidad,
a un mundo donde puedes explorar, crear y descubrir.
Creo que el poder de la abstracción es maravilloso,
y lo es aún más si lo que descubres te permite
explicar o mejorar el mundo real.

Sandra García

Operaciones entre Funciones

Descargar como Notebook

Suma, Resta y Producto

f1[x_] := 2 x - 2

f2[x_] := x - 1

Quiet@Manipulate[

  Plot[{f[x], g[x], op[f[x], g[x]]}, {x, -3, 3}, PlotRange -> 3, 

   GridLines -> All, AspectRatio -> 1, 

   PlotLabels -> {"f(x)", "g(x)"}], {f, {f1 -> "2x-2", 

    Sin -> "Sen(x)", Cos -> "Cos(x)"}}, {g, {f2 -> "x-1", 

    Sin -> "Sen(x)", Cos -> "Cos(x)"}}, {{op, "", 

    "Operación"}, {Plus -> "f[x]+g[x]", Subtract -> "f[x]-g[x]", 

    Times -> "f[x]\[CenterDot]g[x]"}}]

La gráfica azul es f(x), la amarilla es g(x) y la verde corresponde a la operación realizada.

Composición de Funciones

Clear[f, g, ff, gg, gf, fg]

f1[x_] := 2 x + 1

f2[x_] := x^2 + 1

Manipulate[

 Plot[{f[x], g[x], 

   Evaluate@

    Switch[op, fg, f[g[x]], gf, g[f[x]], ff, f[f[x]], gg, 

     g[g[x]]]}, {x, -4, 4}, PlotRange -> 5, 

  PlotStyle -> {Blue, Yellow, Green}, GridLines -> All, 

  AspectRatio -> Automatic], {{f, Sin, "f(x): Azul"}, {f1 -> "2x+1", 

   f2 -> "x²+1", Sin -> "Sen(x)", 

   Cos -> "Cos(x)", Abs -> "|x|"}}, {{g, Cos, "g(x): Amarillo"}, {f1 -> 

    "2x+1", f2 -> "x²+1", 

   Sin -> "Sen(x)", Cos -> "Cos(x)", Abs -> "|x|"}}, {{op, "", 

   "Composición: Verde"}, {fg -> 

    "f∘g", gf -> "g∘f", 

   ff -> "f∘f", gg -> "g∘g"}}]

Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas