Se debe al matemático italiano del siglo XIII Leonardo de Pissa conocido como Fibonacci, quien fue el primer europeo del que se tiene evidencia de haber utilizado los números arábigos. Aunque, sobre la sucesión, hay evidencia de su aparición en épocas anteriores en la India.
A Fibonacci la sucesión le aparece al resolver un problema ideal sobre la cantidad de parejas de conejos que existen en un mes dado sabiendo que se comienza con una pareja recién nacida que el primer mes no tiene cría pero que después cada mes tiene una pareja con la misma característica, así: el primer mes se tiene una pareja; el segundo mes se tiene la misma pareja; el tercer mes la pareja inicial tiene una nueva pareja, es decir ahora se tienen dos parejas; el cuarto mes la pareja inicial tiene una nueva pareja y más la que ya había tenido son 3; el quinto mes la pareja inicial tiene una nueva pareja, la que nació el tercer mes tiene una nueva pareja, así en total son cinco; y así sucesivamente.
Es una sucesión definida de forma recurrente donde sus dos primeros términos son unos y los siguientes se obtienen como la suma de los dos términos anteriores.
En Mathematica la podemos definir como :
fib[1] = 1; fib[2] = 1;
fib[n_] := fib[n - 1] + fib[n - 2]
Table[fib[n], {n, 20}]
{1, 1, 2, 3, 5, 8, 13, 21, 34, 55, 89, 144, 233, 377, 610, 987, 1597, 2584, 4181, 6765}
Aunque Mathematica tiene su propio comando para la sucesión de Fibonacci, que es Fibonacci[ ]
Table[Fibonacci[n], {n, 20}]
{1, 1, 2, 3, 5, 8, 13, 21, 34, 55, 89, 144, 233, 377, 610, 987, 1597, 2584, 4181, 6765}
Propiedades y Aplicaciones
La importancia de la sucesión de Fibonacci radica en el hecho de la cantidad de relaciones que tiene con la naturaleza, como por ejemplo: en las ramas de los árboles, en la disposición de las hojas en el tallo, en las flores de alcachofas y girasoles, en las inflorescencias del brécol romanesco y en la configuración de las piñas de las coníferas. De igual manera, se encuentra en la estructura espiral del caparazón de algunos moluscos, como el nautilus. Muchas formas de la naturaleza tienden a organizarse alrededor de una estructura asociada con la Sucesión de Fibonacci.
Propiedades Matemáticas
Número Áureo
Si creamos la sucesión formada por el cociente de dos términos sucesivos de la sucesión de Fibonacci, el mayor entre el menor, obtenemos que ella tiende al número áureo.
N@Table[Fibonacci[n + 1]/Fibonacci[n], {n, 10, 100, 10}]
{1.61818, 1.61803, 1.61803, 1.61803, 1.61803, 1.61803, 1.61803,
1.61803, 1.61803, 1.61803}
En general,
Limit[Fibonacci[n + 1]/Fibonacci[n], n -> Infinity]
que corresponde al número áureo Φ.
Aunque está definida por una fórmula recurrente podemos determinar una fórmula explícita para su término enésimo, por medio del comando RSolve[ ]:
RSolve[{s[n] == s[n - 1] + s[n - 2], s[1] == 1, s[2] == 1}, s[n], n]
Expresión dada en términos del número áureo.
{1., 1., 2., 3., 5., 8., 13., 21., 34., 55., 89., 144., 233., 377.,
610., 987., 1597., 2584., 4181., 6765.}
Triángulo de Pascal
Guarda también una relación muy cercana con el triángulo de Pascal,
Recordemos de la publicación del 26 de mayo del 2017 sobre El Triángulo de Pascal, que cada elemento lo podemos ver como el Binomial de n con k, Binomial[n,k], donde n es la fila comenzando desde cero y k la posición en la fila iniciando también desde cero. Así, cada número de Fibonacci lo podemos encontrar por:
Recordando que :
p := Floor[n/2];
Table[Sum[Binomial[i, n - 1 - i], {i, p, n - 1}], {n, 20}]
{1, 1, 2, 3, 5, 8, 13, 21, 34, 55, 89, 144, 233, 377, 610, 987, 1597, 2584, 4181, 6765}
Que corresponde a los primeros 20 números de la Sucesión de Fibonacci.
Otras Propiedades
La mayoría son fácilmente comprobables por inducción matemática, pero como es costumbre en el Blog, realizamos una comprobación computacional para los primeros 100000 enteros positivos.
1. Cada número de Fibonacci es el promedio del término que se encuentra dos posiciones antes y el término que se encuentra una posición después.
Apply[And,
Table[(Fibonacci[n - 2] + Fibonacci[n + 1])/2 == Fibonacci[n], {n,
100000}]]
True
2. La suma de los n primeros números más uno es igual al número que ocupa la posición n+2.
Apply[And,
Table[Sum[Fibonacci[i], {i, n}] + 1 == Fibonacci[n + 2], {n,
100000}]]
True
3. La suma alterna de los primeros n números de Fibonacci más uno es igual al término n-1 por (-1)^n.
Apply[And,
Table[Sum[Fibonacci[i] (-1)^i, {i, n}] + 1 ==
Fibonacci[n - 1] (-1)^n, {n, 100000}]]
True
4. La suma de los primeros n términos en posiciones impares de la Sucesión de Fibonacci corresponde al término en la posición 2n.
Apply[And,
Table[Sum[Fibonacci[2 i - 1], {i, n}] == Fibonacci[2 n], {n,
100000}]]
True
5. La suma de los primeros n términos en posiciones pares de la Sucesión de Fibonacci más uno corresponde al término en la posición 2 n+1.
Apply[And,
Table[Sum[Fibonacci[2 i], {i, n}] + 1 == Fibonacci[2 n + 1],
{n, 100000}]]
True
6. La suma de los cuadrados de los primeros n términos de la Sucesión de Fibonacci corresponde al producto de los términos en la posición n y n+1.
Apply[And,
Table[Sum[Fibonacci[i]^2, {i, n}] ==
Fibonacci[n] Fibonacci[n + 1], {n, 100000}]]
True
7. La suma del producto de las parejas de términos consecutivos de la Sucesión de Fibonacci hasta el término 2n corresponde al cuadrado del término 2n.
Apply[And,
Table[Sum[Fibonacci[i - 1] Fibonacci[i], {i, 2 n}] ==
Fibonacci[2 n]^2, {n, 100000}]]
True
8. La suma del producto de las parejas de términos consecutivos de la Sucesión de Fibonacci hasta el término 2n+1 corresponde al cuadrado del término 2n+1 restándole uno.
Apply[And,
Table[Sum[Fibonacci[i - 1] Fibonacci[i], {i, 2 n + 1}] ==
Fibonacci[2 n + 1]^2 - 1, {n, 100000}]]
True
9. El producto de los términos n-1 y n+1 de la Sucesión de Fibonacci menos el cuadrado del término n es igual a (-1)^n. Identidad de Cassini.
Apply[And,
Table[Fibonacci[n + 1] Fibonacci[n - 1] - Fibonacci[n]^2 == (-1)^
n, {n, 100000}]]
True
10. La suma de los cuadrados de los términos n y n+1 de la Sucesión de Fibonacci corresponde al término 2n+1.
Apply[And,
Table[Fibonacci[n + 1]^2 + Fibonacci[n]^2 == Fibonacci[2 n + 1], {n, 100000}]]
True
11. La resta de los cuadrados de los términos n+2 menos n+1 de la Sucesión de Fibonacci corresponde al producto de los términos en la posiciones n y n+3.
Apply[And,
Table[Fibonacci[n + 2]^2 - Fibonacci[n + 1]^2 ==
Fibonacci[n] Fibonacci[n + 3], {n, 100000}]]
True
12. La resta de los cuadrados de los términos n+2 menos n de la Sucesión de Fibonacci corresponde al términos en la posición 2n+2.
Apply[And,
Table[Fibonacci[n + 2]^2 - Fibonacci[n]^2 == Fibonacci[2 n + 2], {n, 100000}]]
True
13. La suma de los cubos de los términos n+2 y n+1 menos el cubo del término en la posición n de la Sucesión de Fibonacci corresponde al términos en la posición 3n+3.
Apply[And,
Table[Fibonacci[n + 2]^3 + Fibonacci[n + 1]^3 - Fibonacci[n]^3 ==
Fibonacci[3 n + 3], {n, 100000}]]
True
14. El máximo común divisor de los números en las posiciones n y m de la Sucesión de Fibonacci corresponde al número en la posición máximo común divisor de m y n.
Apply[And,
Flatten@Table[
GCD[Fibonacci[n], Fibonacci[m]] == Fibonacci[GCD[n, m]],
{n, 1000}, {m, 1000}]]
True
Para aprender más sobre Mathematica ingrese aquí sitio de aprendizaje de Wolfram o en mi website ustamathematica.wixsite.com/basicas
No hay comentarios.:
Publicar un comentario